Papervision Collada Interactivity Demo

I've received a number of requests for an example of how to use my collada interactivity helper functions, so I threw this little demo together. Note that this will only work with simple collada scenes containing a single object.
The first step is commonly overlooked and is crucial for Papervision3D interactivity. We have to enable interactivity on our viewport instance either through its constructor or setting the property directly. In the demo, I set it in the viewport constructor (4th parameter):

viewport = new Viewport3D(800, 600, false, true, true, true);

Next we create our collada instance that we want to interact with. We have to wait until the collada object and its material has completely loaded before we can initialize interactivity so, we need to listen for a FileLoadEvent.LOAD_COMPLETE.cow = new Collada("cow.dae");

scene.addChild(cow);
// before we can add event listeners we need to make sure the 
// object is instantiated completely
cow.addEventListener(FileLoadEvent.LOAD_COMPLETE, handleColladaComplete);

When the LOAD_COMPLETE event is fired we can begin to enable interactivity on the object. In order for the object to dispatch mouse events, the "interactive" property of its material must be set to true. For primative objects, it's very simple to get a handle to their material because you usually explicitly instantiate the material or you can get a handle to it using myPrimativeObj.material. For Collada objects, you can explicitly specify a material and apply it to the object using a MaterialList. Or your .dae file will have the material image file specified internally and the Collada class will instantiate a BitmapFileMaterial automatically. I find the second way to be the most flexible because the designer can name the UV mapped image whatever they'd like and the name can change without breaking the app. However, this way does make getting a handle to the material a little trickier. This is where my helper functions come in. For simple (single object) collada files, these functions return the DirectObject3D instance of the child object and the Material3D instance.

// first we need to get a handle to the child object
var childObj:DisplayObject3D = getColladaDisplayObj(cow);
  
// using the child object we get a handle to its material
var childMat:MaterialObject3D = getColladaNodeMaterial(childObj);

getColladaDisplayObj() uses a nasty String parse method to retrieve the name of the first collada child object. It then uses Collada.getChildByName() and returns a handle to the child DisplayObject3D. I personally would love to see a better solution for this, but for now it works!

var childname:String = String(tempCO.childrenList()).substring(0,String(tempCO.childrenList()).indexOf(": "));
  
returnObj = tempCO.getChildByName(childname);

getColladaMaterial() derives the string name of the first material associated with the given child object. Here I use the Actionscript 3 Core Library's StringUtil class to trim off any leading or trailing space characters from the material name (I'm not sure why they are there but they are). Then I use Collada.getMaterialByName() with the material's name to return a handle to the object's Material3D instance.

var materialName:String = StringUtil.trim(String(colladaNode.materials));
trace("materialName: '" + materialName + "'");
returnVal = colladaNode.getMaterialByName(materialName);

Finally, now that we have handles to the Material and the child object we set the material's interactive flag to true and add our event listeners:

if (childMat != null) {
     // now we have to tell the material to dispatch InteractiveScene3D events
     childMat.interactive = true;
  
     // Now we can add our listeners to the child object
     childObj.addEventListener(InteractiveScene3DEvent.OBJECT_OVER, handleCowOver);
     childObj.addEventListener(InteractiveScene3DEvent.OBJECT_OUT, handleCowOut);
     childObj.addEventListener(InteractiveScene3DEvent.OBJECT_CLICK, handleCowClick);
}

As an added bonus, this demo shows how you can easily apply filters to individual objects in the scene. First you get a handle to the object's layer using Viewport3D.getChildLayer and pass it the instance of the object. Next you create an array of filters and pass that array to the "filters" property of the ViewportLayer.

 private function handleCowOver(event:InteractiveScene3DEvent):void {
     var cowLayer:ViewportLayer = viewport.getChildLayer(cow, true, true);
     cowLayer.filters = [new GlowFilter(0xffee11, 1, 10, 10, 6, 3, false, false)];
}
  
private function handleCowOut(event:InteractiveScene3DEvent):void {
     var cowLayer:ViewportLayer = viewport.getChildLayer(cow, true, true);
     cowLayer.filters = null;
}

The full source for the demo can be downloaded here.